La cassetta degli attrezzi

Ecco - come promesso - il nuovo file Excel per il mese di gennaio.

Ricordo che questo programma fa le seguenti cose:

• Va sul sito della borsa italiana e si scarica rispettivamente i prezzi di chiusura, gli open interest, i volumi di contrattazione e le volatilità implicite delle opzioni Call e Put del mese di Dicembre.
  
  
• Calcola la volatilità implicita media ponderata sulle Call e sulle Put e ne fa il rapporto P/C.
  
  Questa ci serve per calcolarci i livelli di Garcia giornalieri.
  
• Crea il grafico dei volumi di scambio della giornata.
  
  
• Crea lo skew di volatilità implicita.

Grazie.

Grazie anche da parte mia.
Penso che con ogni probabilità non provochi nessun danno perché volumi non ce ne sono ed è sufficiente ignorarlo, ma mi pare che il foglio consideri due volte lo strike 20500.

Grazie anche da parte mia.
Penso che con ogni probabilità non provochi nessun danno perché volumi non ce ne sono ed è sufficiente ignorarlo, ma mi pare che il foglio consideri due volte lo strike 20500.

Per risolvere il problema è sufficiente cambiare manualmente lo strike all'interno della cella G42.
Grazie della segnalazione...

Calcolo del prezzo teorico della Call formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Call_Europea(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
    Tempo = Giorni / 365
If IsMissing(Dividendo) Then
    d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    d2 = d1 - (Volatilità * Sqr(Tempo))
    Call_Europea = Round(Prezzo * Application.NormSDist(d1) - Strike * Exp(-Tasso * Tempo) * Application.NormSDist(d2), 4)
Else
    d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    d2 = d1 - (Volatilità * Sqr(Tempo))
    Call_Europea = Round(Prezzo * Application.NormSDist(d1) * Exp(-Dividendo * Tempo) - Strike * Application.NormSDist(d2) * Exp(-Tasso * Tempo), 4)
End If
End Function

Calcolo del Delta della Put formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Put_Delta(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
    Tempo = Giorni / 365
If IsMissing(Dividendo) Then
    d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    Put_Delta = Round(Application.NormSDist(d1) - 1, 4)
Else
    d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    Put_Delta = Round((Application.NormSDist(d1) - 1) * Exp(-Dividendo * Tempo), 4)
End If
End Function


Calcolo del Theta della Put formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Put_Theta(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
    Tempo = Giorni / 365
If IsMissing(Dividendo) Then
    d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    d2 = d1 - (Volatilità * Sqr(Tempo))
    A = Prezzo * Normale(d1) * Volatilità / (2 * Sqr(Tempo))
    B = Tasso * Strike * Exp(-Tasso * Tempo) * Application.NormSDist(-d2)
    Put_Theta = Round(-A + B, 4)
Else
    d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
    d2 = d1 - (Volatilità * Sqr(Tempo))
    A = Prezzo * Normale(d1) * Volatilità * Exp(-Dividendo * Tempo) / (2 * Sqr(Tempo))
    B = Dividendo * Prezzo * Application.NormSDist(-d1) * Exp(-Dividendo * Tempo)
    C = Tasso * Strike * Exp(-Tasso * Tempo) * Application.NormSDist(-d2)
    Put_Theta = Round(-A - B + C, 4)
End If
End Function

Calcolo del Gamma della Put e della Call formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Gamma(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
        Tempo = Giorni / 365
    If IsMissing(Dividendo) Then
        d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        Gamma = Round(Normale(d1) / (Prezzo * Volatilità * Sqr(Tempo)), 6)
    Else
        d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        Gamma = Round(Normale(d1) * Exp(-Dividendo * Tempo) / (Prezzo * Volatilità * Sqr(Tempo)), 6)
    End If
End Function

Calcolo del Rho della Call formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Call_Rho(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
        Tempo = Giorni / 365
    If IsMissing(Dividendo) Then
        d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        d2 = d1 - (Volatilità * Sqr(Tempo))
        Call_Rho = Round(Strike * Tempo * Exp(-Tasso * Tempo) * Application.NormSDist(d2), 4)
    Else
        d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        d2 = d1 - (Volatilità * Sqr(Tempo))
        Call_Rho = Round(Strike * Tempo * Exp(-Tasso * Tempo) * Application.NormSDist(d2), 4)
    End If
End Function

Calcolo del Rho della Put formula di Black-Scholes-Merton

Codice: Seleziona tutto

Function Put_Rho(Prezzo, Strike, Giorni, Tasso, Volatilità, Optional Dividendo)
        Tempo = Giorni / 365
    If IsMissing(Dividendo) Then
        d1 = (Log(Prezzo / Strike) + (Tasso + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        d2 = d1 - (Volatilità * Sqr(Tempo))
        Put_Rho = Round(-Strike * Tempo * Exp(-Tasso * Tempo) * Application.NormSDist(-d2), 4)
    Else
        d1 = (Log(Prezzo / Strike) + (Tasso - Dividendo + Volatilità ^ 2 / 2) * Tempo) / (Volatilità * Sqr(Tempo))
        d2 = d1 - (Volatilità * Sqr(Tempo))
        Put_Rho = Round(-Strike * Tempo * Exp(-Tasso * Tempo) * Application.NormSDist(-d2), 4)
    End If
End Function